<xsl:stylesheet xmlns:fotex="http://www.tug.org/fotex" xmlns:rng="http://relaxng.org/ns/structure/1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tei="http://www.tei-c.org/ns/1.0" xmlns:teix="http://www.tei-c.org/ns/Examples" xmlns:a="http://relaxng.org/ns/compatibility/annotations/1.0" xmlns:edate="http://exslt.org/dates-and-times" xmlns:xd="http://www.pnp-software.com/XSLTdoc" xmlns:estr="http://exslt.org/strings" xmlns:exsl="http://exslt.org/common" xmlns:fo="http://www.w3.org/1999/XSL/Format" extension-element-prefixes="xd exsl estr edate" exclude-result-prefixes="xd exsl estr edate a fo rng tei teix" version="1.0">
  
  
  <xsl:template name="calculateTableSpecs">
    <xsl:variable name="tds">
      <xsl:for-each select=".//tei:cell">
        <xsl:variable name="stuff">
          <xsl:apply-templates />
        </xsl:variable>
        <cell>
          <xsl:attribute name="col">
            <xsl:number />
          </xsl:attribute>
          <xsl:value-of select="string-length($stuff)" />
        </cell>
      </xsl:for-each>
    </xsl:variable>
    <xsl:variable name="total">
      <xsl:value-of select="sum(exsl:node-set($tds)/cell)" />
    </xsl:variable>
    <xsl:for-each select="exsl:node-set($tds)/cell">
      <xsl:sort select="@col" data-type="number" />
      <xsl:variable name="c" select="@col" />
      <xsl:if test="not(preceding-sibling::cell[$c=@col])">
        <xsl:variable name="len">
          <xsl:value-of select="sum(following-sibling::cell[$c=@col]) + current()" />
        </xsl:variable>
        <xsl:text>
</xsl:text>
        <fo:table-column column-number="{@col}" column-width="{$len div $total * 100}%">
          <xsl:if test="$foEngine='passivetex'">
            <xsl:attribute name="column-align" namespace="http://www.tug.org/fotex">L</xsl:attribute>
          </xsl:if>
        </fo:table-column>
      </xsl:if>
    </xsl:for-each>
    <xsl:text>
</xsl:text>
  </xsl:template>
  
  <xsl:template name="deriveColSpecs">
    <xsl:variable name="no">
      <xsl:call-template name="generateTableID" />
    </xsl:variable>
    <xsl:choose>
      <xsl:when test="$readColSpecFile">
        <xsl:variable name="specs">
          <xsl:value-of select="count(exsl:node-set($tableSpecs)/Info/TableSpec[$no=@xml:id])" />
        </xsl:variable>
        <xsl:choose>
          <xsl:when test="$specs &gt; 0">
            <xsl:for-each select="exsl:node-set($tableSpecs)/Info/TableSpec[$no=@xml:id]/fo:table-column">
              <xsl:copy-of select="." />
            </xsl:for-each>
          </xsl:when>
          <xsl:otherwise>
<!--
 <xsl:message>Build specs for Table <xsl:value-of select="$no"/></xsl:message>
-->
            <xsl:call-template name="calculateTableSpecs" />
          </xsl:otherwise>
        </xsl:choose>
      </xsl:when>
      <xsl:otherwise>
<!--
 <xsl:message>Build specs for Table <xsl:value-of select="$no"/></xsl:message>
-->
        <xsl:call-template name="calculateTableSpecs" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
  
  <xsl:template name="generateTableID">
    <xsl:choose>
      <xsl:when test="@xml:id">
        <xsl:value-of select="@xml:id" />
      </xsl:when>
      <xsl:otherwise>
        <xsl:text>Table-</xsl:text>
        <xsl:number level="any" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>
</xsl:stylesheet>